## identity-service-task-role
data "aws_iam_policy_document" "ecs_assume_role" {
  statement {
    sid     = "AllowAssumeRoleFromidentityTasks"
    effect  = "Allow"
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["ecs-tasks.amazonaws.com"]
    }
  }
}

data "aws_iam_policy_document" "identity_task_role" {
  statement {
    sid = "identityServiceSpecificAccess"
    effect = "Allow"
    actions = [
      "cloudformation:DescribeStackResources",
      "autoscaling:DescribeAutoScalingInstances",
      "cognito-idp:*"
    ]
    resources = ["*"]
  }
  statement {
    sid = "IdentityTaskRoleAccessToSecretsManager"
    effect = "Allow"
    actions = [
      "secretsmanager:DescribeSecret",
      "secretsmanager:GetSecretValue",
    ]
    resources = [
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:identity-service-client-secret-??????",
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:rsa_key_identity_server-??????",
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:mysql_pass_identity_server-??????",
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:spring_cloud_config-??????",
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:internal_aws_secret_access_key-??????"
    ]

  }
  statement {
    sid = "BillingECSTaskExecution"
    effect = "Allow"
    actions = [
      "ecr:GetAuthorizationToken",
      "ecr:BatchCheckLayerAvailability",
      "ecr:GetDownloadUrlForLayer",
      "ecr:BatchGetImage",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
    resources = ["*"]
  }
}

resource "aws_iam_policy" "identity_task_role" {
  name = "identity-service-policy${local.iam_suffix}"
  policy = data.aws_iam_policy_document.identity_task_role.json
}

resource "aws_iam_role" "identity_task_role" {
  name = "${local.service_name}-task-role${local.iam_suffix}"
  assume_role_policy = data.aws_iam_policy_document.ecs_assume_role.json
}

resource "aws_iam_role_policy_attachment" "profile_internal_policy_attach" {
  role = aws_iam_role.identity_task_role.name
  policy_arn = aws_iam_policy.internal_profile_policy_copy.arn
}

resource "aws_iam_policy" "internal_profile_policy_copy" {
  name = "${var.service_name}-profile-internal${local.iam_suffix}"
  policy = data.terraform_remote_state.mop_core.outputs.tf_profile_internal_policy_document
}


resource "aws_iam_role_policy_attachment" "identity_task_role_policy_attach" {
  role = aws_iam_role.identity_task_role.name
  policy_arn = aws_iam_policy.identity_task_role.arn
}

#
##
### if Sandbox then create a user with the same policies for localhost MOP
##
#

# create an IAM user for the localhost service
resource "aws_iam_user" "identity_service" {
  name = "identity_service${local.iam_suffix}"
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}
# this credential lives in mop-utils/sandbox-credentials
resource "aws_iam_access_key" "identity_service" {
  user = "${aws_iam_user.identity_service[0].name}${local.iam_suffix}"
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}

# attach the same policies held by the task role
resource "aws_iam_user_policy_attachment" "profile_internal_identity" {
  user       = aws_iam_user.identity_service[0].name
  policy_arn = aws_iam_policy.internal_profile_policy_copy.arn
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}
resource "aws_iam_user_policy_attachment" "identity_task_role_policy_attach" {
  user       = aws_iam_user.identity_service[0].name
  policy_arn = aws_iam_policy.identity_task_role.arn
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}