module auth_service_failover {

  providers = {
    aws = aws.ap-south-1
  }

  source = "git::ssh://git@bitbucket.org/netfoundry/nf-mop-tf.git//modules/aws/ecs_fargate_service"

  service_name        = local.service_name
  container_count     = local.failover_container_count
  // use failover
  task_definition     = data.template_file.task_definition_failover.rendered
  task_role_arn       = aws_iam_role.auth_task_role.arn
  // use failover
  registry_arn        = aws_service_discovery_service.auth_service_failover.arn
  // use failover
  ecs_cluster_id      = data.terraform_remote_state.mop_core_failover.outputs.ecs_cluster_id
  cpu                 = "1024"
  memory              = "2048"
  execution_role_arn = aws_iam_role.auth_task_role.arn
  // use failover
  security_groups     = [aws_security_group.auth_service_failover.id,data.terraform_remote_state.mop_core_failover.outputs.sg_alb_id]
  // use failover
  subnets             = data.terraform_remote_state.mop_core_failover.outputs.vpc_subnet_private_ids
  log_retention       = 30
}

data template_file "task_definition_failover" {
  template = file("${path.module}/templates/task-definition.json")

  vars = {
    image_url             = "745435643501.dkr.ecr.us-east-1.amazonaws.com/authorization:${data.aws_ssm_parameter.container_image.value}"
    #image_url             = "netfoundry/auth:${data.aws_ssm_parameter.container_image.value}"
    #docker_hub_secret_arn = data.terraform_remote_state.mop_core.outputs.dockerhub_secret_arn
    container_name        = local.service_name
    container_port        = local.container_port
    grpc_port             = local.grpc_port
    service_endpoint      = "${local.short_name}.mop.local"
    health_check_path     = local.health_check_path
    // use failover
    log_group_region      = local.failover_region
    log_group_name        = module.auth_service.cwlog_group_name
    spring_profiles_active = local.deploy_env_name
    # Setting the config_uri in the task defnition
    spring_cloud_config_uri   = "http://config-service.mop.local:8888"
    spring_cloud_config_label = local.spring_config_label
    aws_default_region        = var.region[terraform.workspace]
    # properties settings
    subdomain                  = local.subdomain
    internal_aws_access_key_id = data.aws_ssm_parameter.iam_user_profile_internal_access_key_id.value
    #sqs_queue_name             = "${data.aws_ssm_parameter.sqs_mop_events_application_name.value}"
    sqs_queue_name              = data.terraform_remote_state.mop_core.outputs.sqs_mop_events_application_name
    rds_endpoint               = module.rds_mysql_permission.rds_instance_address
    rds_username               = module.rds_mysql_permission.rds_username
    mysql_pass                = data.aws_secretsmanager_secret.mysql_pass_permission.arn
    spring_cloud_config_password = data.aws_secretsmanager_secret.spring_cloud_config.arn
    internal_aws_secret       = data.aws_secretsmanager_secret.internal_aws_secret_access_key.arn
    auth0_client_id       = auth0_client.client.client_id
    auth0_client_secret   = auth0_client.client.client_secret
    redis_cluster_address = data.terraform_remote_state.mop_core.outputs.redis_address
    redis_failover_address = data.terraform_remote_state.mop_core.outputs.redis_reader_address
    deploy_env = local.deploy_env_name

    // make multi-region friendly
    auth0_issuer = "https://netfoundry-${var.auth0_issuer_map[terraform.workspace]}.auth0.com/"
  }
}

resource "aws_service_discovery_service" "auth_service_failover" {

  provider = aws.ap-south-1

  // WARNING - THIS IS NOT LIKE THE OTHER SERVICES. Other services use the -service suffix
  name = "auth"

  dns_config {
    namespace_id = data.terraform_remote_state.mop_core_failover.outputs.ecs_private_discovery_namespace_id

    dns_records {
      ttl  = 10
      type = "A"
    }

    routing_policy = "MULTIVALUE"
  }

  health_check_custom_config {
    failure_threshold = 1
  }
}